alex/beta-minecraft-rust

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

struct Vertex
{
    float2 position;
    float2 uv;
    uint color;
    int texture;
};

struct Push
{
    Vertex* vertices;
    float2 size;
};

[[vk::push_constant]] Push push;
[[vk::binding(0, 0)]] Texture2D textures[];
[[vk::binding(1, 0)]] SamplerState samplers[];

struct Varyings
{
    float4 position : SV_Position;
    float2 uv : TEXCOORD0;
    float4 color : COLOR0;
    nointerpolation int texture : TEXCOORD1;
};

[shader("vertex")]
Varyings vertexMain(uint index : SV_VulkanVertexID)
{
    Vertex v = push.vertices[index];
    Varyings o;
    o.position = float4(v.position.x / push.size.x * 2.0 - 1.0, 1.0 - v.position.y / push.size.y * 2.0, 1.0, 1.0);
    o.uv = v.uv;
    o.color = unpackUnorm4x8ToFloat(v.color);
    o.texture = v.texture;
    return o;
}

// Texture flags: smooth sampling, and darkening the screen by the texel color (`GL_ZERO`,
// `GL_ONE_MINUS_SRC_COLOR`) for gray textures.
static const int BLUR = 1 << 16;
static const int DARKEN = 1 << 17;
// The crosshair's inverting blend: transparent texels must leave the screen unchanged.
static const int INVERT = 1 << 18;

[shader("fragment")]
float4 fragmentMain(Varyings i) : SV_Target
{
    float4 color = i.color;
    if (i.texture >= 0)
    {
        uint sampler = (i.texture & BLUR) != 0 ? 1 : 0;
        color *= textures[NonUniformResourceIndex(i.texture & 0xffff)].Sample(samplers[NonUniformResourceIndex(sampler)], i.uv);
    }
    if (i.texture >= 0 && (i.texture & DARKEN) != 0)
        return float4(0.0, 0.0, 0.0, color.r);
    if (i.texture >= 0 && (i.texture & INVERT) != 0)
        return float4(color.a >= 0.1 ? color.rgb : float3(0.0), 0.0);
    return color;
}