alex/beta-minecraft-rust

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

// Sky planes, sunrise fan, sun and moon. Positions are relative to the camera.

struct SkyVertex
{
    float3 position;
    float2 uv;
    uint color;  // RGBA8
};

struct Push
{
    float4x4 viewProjection;
    SkyVertex* vertices;
    float4 fogColor;
    float4 camera;
    float fogStart;
    float fogEnd;
    uint fog;
    int texture;  // negative for untextured
};

[[vk::push_constant]] Push push;
[[vk::binding(0, 0)]] Texture2D textures[];
[[vk::binding(1, 0)]] SamplerState samplers[];

struct Varyings
{
    float4 position : SV_Position;
    float2 uv : TEXCOORD0;
    float4 color : COLOR0;
    float distance : TEXCOORD1;
};

[shader("vertex")]
Varyings vertexMain(uint vertexIndex : SV_VulkanVertexID)
{
    SkyVertex v = push.vertices[vertexIndex];
    Varyings o;
    o.position = mul(push.viewProjection, float4(v.position, 1.0));
    o.uv = v.uv;
    o.color = unpackUnorm4x8ToFloat(v.color);
    o.distance = length(v.position - push.camera.xyz);
    return o;
}

[shader("fragment")]
float4 fragmentMain(Varyings i) : SV_Target
{
    float4 color = i.color;
    if (push.texture >= 0)
        color *= textures[push.texture].Sample(samplers[0], i.uv);
    if (push.fog != 0)
    {
        // A negative start selects GL_EXP fog with the negated start as density
        float fog = push.fogStart < 0.0
            ? exp(push.fogStart * i.distance)
            : saturate((push.fogEnd - i.distance) / (push.fogEnd - push.fogStart));
        color.rgb = lerp(push.fogColor.rgb, color.rgb, fog);
    }
    return color;
}